SCR_AnalyticsInventory.c

Go to the documentation of this file.

class SCR_AnalyticsInventory
{
    protected ref SCR_InventoryData m_Inventory = new SCR_InventoryData();
    protected ref SCR_AnalyticsDelayedSend m_DelayedSend = new SCR_AnalyticsDelayedSend();
    protected ref array<float> m_aOpenWeights = {};
    protected ref array<float> m_aCloseWeights = {};
    
    //------------------------------------------------------------------------------------------------
    void OpenInventory(float currentWeight)
    {
        m_DelayedSend.Start();
        
        if (!m_DelayedSend.IsAdditive())
        {
            m_Inventory = new SCR_InventoryData();
            m_aOpenWeights.Clear();
            m_aCloseWeights.Clear();
        }
        
        m_aOpenWeights.Insert(currentWeight);
    }
 
    //------------------------------------------------------------------------------------------------
    void CloseInventory(float currentWeight)
    {
        m_DelayedSend.Stop();
 
        if (m_DelayedSend.IsAdditive())
            m_Inventory.amt_inv_time_spent += m_DelayedSend.GetTimeSpent();
        else
            m_Inventory.amt_inv_time_spent = m_DelayedSend.GetTimeSpent();
 
        m_aCloseWeights.Insert(currentWeight);
    }
    
    //------------------------------------------------------------------------------------------------
    void Update(float deltaSeconds)
    {
        m_DelayedSend.Update(deltaSeconds);
    }
    
    //------------------------------------------------------------------------------------------------
    bool IsReadyToSend()
    {
        return m_DelayedSend.IsReadyToSend();
    }
    
    //------------------------------------------------------------------------------------------------
    void ResetReadyToSend()
    {
        m_DelayedSend.ResetReadyToSend();
    }
    
    //------------------------------------------------------------------------------------------------
    void InteractWithItem(SCR_EAnalyticalItemSlotType itemSlotType)
    {
        switch (itemSlotType)
        {
            case SCR_EAnalyticalItemSlotType.HORIZONTAL:
                m_Inventory.cnt_inv_interactions_horizontal += 1;
                break;
 
            case SCR_EAnalyticalItemSlotType.VERTICAL:
                m_Inventory.cnt_inv_interactions_vertical += 1;
                break;
 
            case SCR_EAnalyticalItemSlotType.CHARACTER_STORAGE:
                m_Inventory.cnt_inv_interactions_character_storage += 1;
                break;
 
            case SCR_EAnalyticalItemSlotType.VICINITY:
                m_Inventory.cnt_inv_interactions_vicinity += 1;
                break;
            
            case SCR_EAnalyticalItemSlotType.OTHER:
                // we don't track other types
                break;
        }
    }
 
    //------------------------------------------------------------------------------------------------
    void UseHealing()
    {
        m_Inventory.cnt_inv_healing += 1;   
    }
    
    //------------------------------------------------------------------------------------------------
    void UseExamination()
    {
        m_Inventory.cnt_inv_examination += 1;
    }
    
    //------------------------------------------------------------------------------------------------
    SCR_InventoryData GetClonedData()
    {
        SCR_InventoryData data = SCR_InventoryData.Cast(m_Inventory.Clone());
        data.array_inv_weight_on_open = ArrayToString(m_aOpenWeights);
        data.array_inv_weight_on_close = ArrayToString(m_aCloseWeights);
        return data;
    }
    
    //------------------------------------------------------------------------------------------------
    protected string ArrayToString(array<float> arr)
    {
        string result = "[";
        bool firstElement = true;
        foreach (float val : arr)
        {
            if (firstElement)
                result += val.ToString(lenDec: 3);
            else
                result += "," + val.ToString(lenDec: 3);
 
            firstElement = false;
        }
        return result + "]";
    }
}