SCR_AttributesHelper.c

Go to the documentation of this file.

class SCR_AttributesHelper
{
    protected static const string ENTRY_DELIMITER = ";";
    protected static const string VALUE_DELIMITER = "|";
 
    //------------------------------------------------------------------------------------------------
    static ParamEnumArray ParamFromTitles(string titles)
    {
        array<string> titlesArray = {};
        titles.Split(ENTRY_DELIMITER, titlesArray, false);
        ParamEnumArray params = new ParamEnumArray();
        foreach (int i, string title : titlesArray)
        {
            if (title) // !.IsEmpty() not necessary
                params.Insert(new ParamEnum(title.Trim(), i.ToString()));
        }
 
        return params;
    }
 
    //------------------------------------------------------------------------------------------------
    static ParamEnumArray ParamFromDescriptions(typename enumType, string descriptions)
    {
        array<string> descriptionsArray = {};
        descriptions.Split(ENTRY_DELIMITER, descriptionsArray, false);
        int variableCount = enumType.GetVariableCount();
        ParamEnumArray params = new ParamEnumArray();
        foreach (int i, string description : descriptionsArray)
        {
            int enumValue;
            if (description && enumType.GetVariableValue(NULL, i, enumValue))
                params.Insert(new ParamEnum(enumType.GetVariableName(i), enumValue.ToString(), description.Trim()));
        }
 
        return params;
    }
 
    //------------------------------------------------------------------------------------------------
    static ParamEnumArray ParamFromEntries(string document)
    {
        array<string> entries = {};
        document.Split(ENTRY_DELIMITER, entries, false);
        array<string> values = {}; // Reuse instance of values array to avoid unnecessary allocations.
        ParamEnumArray params = new ParamEnumArray();
        foreach (string entry : entries)
        {
            string title, value, description;
            SplitEntryIntoValues(entry, values, title, value, description, VALUE_DELIMITER);
            params.Insert(new ParamEnum(title.Trim(), value.Trim(), description.Trim()));
            values.Clear();
        }
 
        return params;
    }
 
    //------------------------------------------------------------------------------------------------
    static string ParamToEntries(ParamEnumArray enumArray)
    {
        string result;
        foreach (int i, ParamEnum paramEnum : enumArray)
        {
            result += string.Format("%2%1%3%1%4%5", VALUE_DELIMITER, paramEnum.m_Key, paramEnum.m_Value, paramEnum.m_Desc, ENTRY_DELIMITER);
        }
 
        return result;
    }
 
    //------------------------------------------------------------------------------------------------
    static void SplitEntryIntoValues(string entry, notnull array<string> values, out string title, out string value, out string description, string delimiter = VALUE_DELIMITER)
    {
        entry.Split(delimiter, values, false);
        int valuesCount = values.Count();
        if (valuesCount <= 0)
            return;
 
        title = values[0];
        if (valuesCount <= 1)
            return;
 
        value = values[1];
        if (valuesCount <= 2)
            return;
 
        description = values[2];
    }
}