SCR_AutotestResult.c

Go to the documentation of this file.

class SCR_AutotestResult : TestResultBase
{
    protected bool m_bIsSuccess;
    protected string m_sFailureReason;
 
    //------------------------------------------------------------------------------------------------
    static SCR_AutotestResult AsSuccess()
    {
        SCR_AutotestResult result = new SCR_AutotestResult(true);
        return result;
    }
 
    //------------------------------------------------------------------------------------------------
    static SCR_AutotestResult AsFailure(string reason, string param1 = "", string param2 = "", string param3 = "")
    {
        SCR_AutotestResult result = new SCR_AutotestResult(false, string.Format(reason, param1, param2, param3));
        return result;
    }
 
    //------------------------------------------------------------------------------------------------
    string GetFailureReason()
    {
        return m_sFailureReason;
    }
 
    //------------------------------------------------------------------------------------------------
    override bool Failure()
    {
        return !m_bIsSuccess;
    }
 
    //------------------------------------------------------------------------------------------------
    override string FailureText()
    {
        return string.Format(
            "<failure type=\"Result\">%1</failure>",
            TestHarness.EscapeForXml(m_sFailureReason)
        );
    }
 
    //------------------------------------------------------------------------------------------------
    // Private constructor enforces usage of static factory methods for instantiation.
    private void SCR_AutotestResult(bool isSuccess, string reason = "")
    {
        m_bIsSuccess = isSuccess;
        m_sFailureReason = reason;
    }
}