SCR_AnalyticsDataCollectionHelper.c

Go to the documentation of this file.

class SCR_AnalyticsDataCollectionHelper
{
    //------------------------------------------------------------------------------------------------
    static string GetEntityPrefabName(notnull IEntity entity)
    {
        string entityName;
 
        EntityPrefabData entityPrefabData = entity.GetPrefabData();
        if (!entityPrefabData)
            return entityName;
 
        entityName = entityPrefabData.GetPrefab().GetName();
        
        return GetShortEntityPrefabName(entityName);
    }
    
    //------------------------------------------------------------------------------------------------
    static int GetEntitySupplyCost(IEntity entity)
    {
        SCR_EditableEntityComponent editableEntityComponent = SCR_EditableEntityComponent.GetEditableEntity(entity);
        if (!editableEntityComponent)
            return 0;
 
        array<ref SCR_EntityBudgetValue> budgets = {};
        editableEntityComponent.GetEntityBudgetCost(budgets, entity);
 
        foreach (SCR_EntityBudgetValue budget : budgets)
        {
            // We only care about Campaign budget
            if (budget.GetBudgetType() == EEditableEntityBudget.CAMPAIGN)
                return budget.GetBudgetValue();
        }
 
        return 0;
    }
    
    //------------------------------------------------------------------------------------------------
    static string GetShortEntityPrefabName(string entityPrefabName)
    {
        array<string> pieces = {};
        entityPrefabName.Split("/", pieces, true);
 
        string shortName;
        if (pieces.Count() > 0)
            shortName = pieces[pieces.Count() - 1];
 
        return shortName;
    }
 
    //------------------------------------------------------------------------------------------------
    static string GetShortDataArray(string dataArray)
    {
        int firstWhiteSpaceIndex = dataArray.IndexOf(" ");
        if (firstWhiteSpaceIndex < 1)
            return string.Empty;
 
        return dataArray.Substring(firstWhiteSpaceIndex +1, dataArray.Length() - 1 - firstWhiteSpaceIndex);
    }
 
    //------------------------------------------------------------------------------------------------
    static string GetShortModuleName(string moduleName)
    {
        array<string> pieces = {};
        moduleName.Split("<", pieces, true);
 
        string shortName;
 
        if (pieces.Count() > 0)
            shortName = pieces[0];
 
        shortName.Split("_", pieces, true);
 
        if (pieces.Count() > 0)
            shortName = pieces[pieces.Count() - 1];
 
        return shortName;
    }
}