SCR_AutotestCaseBase.c

Go to the documentation of this file.

class SCR_AutotestCaseBase : TestBase
{
    //------------------------------------------------------------------------------------------------
    TestResultBase AssertTrue(bool expression, string msg)
    {
        TestResultBase result = GetResult();
        if (result && result.Failure())
            return result;
 
        if (!expression)
        {
            result = SCR_AutotestResult.AsFailure("AssertTrue: %1", msg);
            SetResult(result);
        }
 
        return result;
    }
 
    //------------------------------------------------------------------------------------------------
    notnull TestResultBase SetResultSuccess(bool force = false)
    {
        TestResultBase result = GetResult();
        if (!force && result && result.Failure())
            return result;
        
        result = SCR_AutotestResult.AsSuccess();
        SetResult(result);
 
        return result;
    }
 
    //------------------------------------------------------------------------------------------------
    notnull TestResultBase SetResultFailure(string reason, string param1 = "", string param2 = "", string param3 = "")
    {
        TestResultBase result = GetResult();
        if (result && result.Failure())
            return result;
        
        result = SCR_AutotestResult.AsFailure(reason, param1, param2, param3);
        SetResult(result);
 
        return result;
    }
 
    //------------------------------------------------------------------------------------------------
    TestSuite GetSuite()
    {
        for (int i, countSuites = TestHarness.GetNSuites(); i < countSuites; i++)
        {
            TestSuite suite = TestHarness.GetSuite(i);
            for (int j, countTests = suite.GetNTests(); j < countTests; j++)
            {
                TestBase test = suite.GetTest(j);
                if (test.Type() == this.Type())
                    return suite;
            }
        }
 
        return null;
    }
 
    //------------------------------------------------------------------------------------------------
    void Print(string msg, LogLevel level = LogLevel.NORMAL)
    {
        SCR_AutotestHarness.GetLogger().Log("\t"+msg, level);
    }
 
    //------------------------------------------------------------------------------------------------
    void PrintFormat(string fmt, string param1 = "", string param2 = "", string param3 = "", LogLevel level = LogLevel.NORMAL)
    {
        SCR_AutotestHarness.GetLogger().Log(string.Format("\t"+fmt, param1, param2, param3), level);
    }
 
    //------------------------------------------------------------------------------------------------
    void PrintOnce(string msg, LogLevel level = LogLevel.NORMAL)
    {
        SCR_AutotestHarness.GetLogger().LogOnce("\t"+msg, level);
    }
 
    //------------------------------------------------------------------------------------------------
    [Step(EStage.Setup)]
    private void Setup_Logger()
    {
        SCR_AutotestHarness._SetActiveTestCase(this);
    }
 
    //------------------------------------------------------------------------------------------------
    [Step(EStage.TearDown)]
    private void TearDown_PrintTestResult()
    {
        SCR_AutotestHarness.GetLogger().LogTestCaseResult(this);
    }
 
    //------------------------------------------------------------------------------------------------
    [Step(EStage.TearDown)]
    private void TearDown_Logger()
    {
        SCR_AutotestHarness._SetActiveTestCase(null);
    }
}