SCR_ResourceConsumerServicePoint.c

Go to the documentation of this file.

[BaseContainerProps(configRoot: true)]
class SCR_ResourceConsumerServicePoint : SCR_ResourceConsumer
{
    protected SCR_ServicePointComponent m_ServicePointComponent;
    protected ref set<SCR_ResourceConsumerMilitaryBase> m_aBaseConsumers;
    
    //------------------------------------------------------------------------------------------------
    override bool CanInteractWith(notnull SCR_ResourceContainer container)
    {
        if (m_aBaseConsumers)
        {
            foreach (SCR_ResourceConsumerMilitaryBase baseConsumer : m_aBaseConsumers)
            {
                if (baseConsumer && container.IsInteractorLinked(baseConsumer))
                    return super.CanInteractWith(container);
            }
        }
        
        return super.CanInteractWith(container);
    }
    
    //------------------------------------------------------------------------------------------------
    override void OnResourceGridUpdated(notnull SCR_ResourceGrid grid)
    {
        if (m_aBaseConsumers)
        {
            foreach (SCR_ResourceConsumerMilitaryBase baseConsumer : m_aBaseConsumers)
            {
                if (baseConsumer)
                    grid.UpdateInteractor(baseConsumer);
            }
        }
        
        super.OnResourceGridUpdated(grid);
    }
    
    //------------------------------------------------------------------------------------------------
    void OnBaseRegistered(notnull SCR_ServicePointComponent servicePoint, notnull SCR_MilitaryBaseComponent base)
    {
        SCR_ResourceComponent baseResourceComponent = SCR_ResourceComponent.Cast(base.GetOwner().FindComponent(SCR_ResourceComponent));
        
        if (!baseResourceComponent)
            return;
        
        SCR_ResourceConsumerMilitaryBase baseConsumer = SCR_ResourceConsumerMilitaryBase.Cast(baseResourceComponent.GetConsumer(m_eGeneratorIdentifier, m_eResourceType));
        
        if (!baseConsumer)
            return;
        
        if (!m_aBaseConsumers)
            m_aBaseConsumers = new set<SCR_ResourceConsumerMilitaryBase>();
        
        m_aBaseConsumers.Insert(baseConsumer);
        baseConsumer.GetOnBaseContainerRegistered().Insert(OnBaseContainerRegistered);
        baseConsumer.GetOnBaseContainerUnregistered().Insert(OnBaseContainerUnregistered);
        
        SCR_ResourceContainerQueueBase containerQueue = baseConsumer.GetContainerQueue();
        SCR_ResourceContainer container;
        
        for (int idx = containerQueue.GetContainerCount() - 1; idx >= 0; --idx)
        {
            container = containerQueue.GetContainerAt(idx);
            
            if (!container)
                continue;
            
            OnBaseContainerRegistered(baseConsumer, container);
        }
    }
    
    //------------------------------------------------------------------------------------------------
    void OnBaseUnregistered(notnull SCR_ServicePointComponent servicePoint, notnull SCR_MilitaryBaseComponent base)
    {
        SCR_ResourceComponent baseResourceComponent = SCR_ResourceComponent.Cast(base.GetOwner().FindComponent(SCR_ResourceComponent));
        
        if (!baseResourceComponent)
            return;
        
        SCR_ResourceConsumerMilitaryBase baseConsumer = SCR_ResourceConsumerMilitaryBase.Cast(baseResourceComponent.GetConsumer(m_eGeneratorIdentifier, m_eResourceType));
        
        if (!baseConsumer)
            return;
        
        if (m_aBaseConsumers)
            m_aBaseConsumers.RemoveItem(baseConsumer);
        
        baseConsumer.GetOnBaseContainerRegistered().Remove(OnBaseContainerRegistered);
        baseConsumer.GetOnBaseContainerUnregistered().Remove(OnBaseContainerUnregistered);
        
        SCR_ResourceContainerQueueBase containerQueue = baseConsumer.GetContainerQueue();
        SCR_ResourceContainer container;
        
        for (int idx = containerQueue.GetContainerCount() - 1; idx >= 0; --idx)
        {
            container = containerQueue.GetContainerAt(idx);
            
            if (!container)
                continue;
            
            OnBaseContainerUnregistered(baseConsumer, container);
        }
    }
    
    //------------------------------------------------------------------------------------------------  
    protected void OnBaseContainerRegistered(notnull SCR_ResourceConsumerMilitaryBase consumer, notnull SCR_ResourceContainer container)
    {
        if (!m_aBaseConsumers)
            return;
        
        if (!container.IsInteractorLinked(this))
            RegisterContainer(container);
    }
    
    //------------------------------------------------------------------------------------------------
    protected void OnBaseContainerUnregistered(notnull SCR_ResourceConsumerMilitaryBase consumer, notnull SCR_ResourceContainer container)
    {
        if (!m_aBaseConsumers)
            return;
        
        foreach (SCR_ResourceConsumerMilitaryBase baseConsumer : m_aBaseConsumers)
        {
            if (baseConsumer && container.IsInteractorLinked(baseConsumer))
                return;
        }
        
        UnregisterContainer(container);
    }
    
    //------------------------------------------------------------------------------------------------
    override void Initialize(notnull IEntity owner)
    {
        super.Initialize(owner);
        
        m_ServicePointComponent = SCR_ServicePointComponent.Cast(GetOwner().FindComponent(SCR_ServicePointComponent));
        
        if (!m_ServicePointComponent)
            return;
        
        m_ServicePointComponent.GetOnBaseRegistered().Insert(OnBaseRegistered);
        m_ServicePointComponent.GetOnBaseUnregistered().Insert(OnBaseUnregistered);
    }
    
    //------------------------------------------------------------------------------------------------
    override void Clear()
    {
        super.Clear();
        
        if (!m_ServicePointComponent)
            return;
        
        m_ServicePointComponent.GetOnBaseRegistered().Remove(OnBaseRegistered);
        m_ServicePointComponent.GetOnBaseUnregistered().Remove(OnBaseUnregistered);
    }
}