SCR_RippleFireIntervalAction.c

Go to the documentation of this file.

class SCR_RippleFireIntervalAction : SCR_AdjustSignalAction
{
    protected SCR_FireModeManagerComponent fireModeManager;
 
    //------------------------------------------------------------------------------------------------
    override void Init(IEntity pOwnerEntity, GenericComponent pManagerComponent)
    {
        super.Init(pOwnerEntity, pManagerComponent);
        
        fireModeManager = SCR_FireModeManagerComponent.Cast(GetOwner().FindComponent(SCR_FireModeManagerComponent));
        
        if (pOwnerEntity.GetParent())
            m_SoundComponent = SoundComponent.Cast(pOwnerEntity.GetParent().FindComponent(SoundComponent));
    }
    
    //------------------------------------------------------------------------------------------------
    override bool CanBeShownScript(IEntity user)
    {
        if (fireModeManager && fireModeManager.GetFireMode() == EWeaponGroupFireMode.RIPPLE)
            return true;
        
        return false;
    }
 
    //------------------------------------------------------------------------------------------------
    override protected bool OnSaveActionData(ScriptBitWriter writer)
    {
        bool saved = super.OnSaveActionData(writer);
        bool noChanges = float.AlmostEqual(m_fTargetValue, fireModeManager.GetRippleInterval());
        writer.WriteBool(noChanges);
        if (noChanges)
            return saved;
 
        writer.WriteFloat(m_fTargetValue);
        if (fireModeManager)
            fireModeManager.SetRippleInterval(m_fTargetValue);
 
        return saved;
    }
 
    //------------------------------------------------------------------------------------------------
    override protected bool OnLoadActionData(ScriptBitReader reader)
    {
        bool loaded = super.OnLoadActionData(reader);
        bool noChanges;
        reader.ReadBool(noChanges);
        if (noChanges)
            return loaded; 
        
        float value;
        reader.ReadFloat(value);
        if (m_bIsAdjustedByPlayer || float.AlmostEqual(value, fireModeManager.GetRippleInterval()))
            return loaded;
        
        m_fTargetValue = value;
        if (fireModeManager)
            fireModeManager.SetRippleInterval(m_fTargetValue);
        
        return loaded;
    }
 
    //------------------------------------------------------------------------------------------------
    override bool GetActionNameScript(out string outName)
    {
        if (!fireModeManager)
            return false;
        
        UIInfo info = GetUIInfo();
        if (!info)
            return false;
        
        outName = info.GetName() + " " + fireModeManager.GetRippleInterval();
 
        return true;
    }
}