SCR_ScenarioFrameworkTask.c

Go to the documentation of this file.

class SCR_ScenarioFrameworkTaskClass : SCR_ExtendedTaskClass
{
};
 
class SCR_ScenarioFrameworkTask : SCR_ExtendedTask
{
    protected IEntity                                               m_Asset;
    protected SCR_ScenarioFrameworkLayerTask                        m_LayerTask;
    protected SCR_ScenarioFrameworkSlotTask                         m_SlotTask;
    
    //------------------------------------------------------------------------------------------------
    SCR_ETaskNotificationSettings GetTaskNotificationSettings()
    {
        if (m_LayerTask)
            return m_LayerTask.m_eTaskNotificationSettings;
        
        return 0;
    }
    
    //------------------------------------------------------------------------------------------------
    void SetLayerTask(SCR_ScenarioFrameworkLayerTask layer)
    {
        m_LayerTask = layer;
    }
 
    //------------------------------------------------------------------------------------------------
    SCR_ScenarioFrameworkLayerTask GetLayerTask()
    {
        return m_LayerTask;
    }
 
    //------------------------------------------------------------------------------------------------
    void HookTaskAsset(IEntity object)
    {
        if (!object)
            return;
        
        m_Asset = object;
        
        SCR_GarbageSystem garbageSystem = SCR_GarbageSystem.GetByEntityWorld(m_Asset);
        if (garbageSystem)
            garbageSystem.UpdateBlacklist(m_Asset, true);
    }
 
    //------------------------------------------------------------------------------------------------
    IEntity GetAsset()
    {
        return m_Asset;
    }
    
    //------------------------------------------------------------------------------------------------
    void SetSlotTask(SCR_ScenarioFrameworkSlotTask slotTask)
    {
        m_SlotTask = slotTask;
    }
    
    //------------------------------------------------------------------------------------------------
    SCR_ScenarioFrameworkSlotTask GetSlotTask()
    {
        return m_SlotTask;
    }
    
    //------------------------------------------------------------------------------------------------
    void SetTaskExecutionBriefing(string text)
    {
        Rpc_SetTaskExecutionBriefing(text);
        Rpc(Rpc_SetTaskExecutionBriefing, text);
    }
 
    //------------------------------------------------------------------------------------------------
    [RplRpc(RplChannel.Reliable, RplRcver.Broadcast)]
    protected void Rpc_SetTaskExecutionBriefing(string text)
    {
        SCR_ScenarioFrameworkTaskData frameworkData = SCR_ScenarioFrameworkTaskData.Cast(m_TaskData);
        if (!frameworkData)
            return;
        
        frameworkData.m_bCustomBriefing = true;
        frameworkData.m_sTaskExecutionBriefing = text;
    }
 
    //------------------------------------------------------------------------------------------------
    string GetTaskExecutionBriefing()
    { 
        SCR_ScenarioFrameworkTaskData frameworkData = SCR_ScenarioFrameworkTaskData.Cast(m_TaskData);
        if (!frameworkData)
            return string.Empty;
        
        return frameworkData.m_sTaskExecutionBriefing;
    }
    
    //------------------------------------------------------------------------------------------------
    override bool RplSave(ScriptBitWriter writer)
    {
        if (!super.RplSave(writer))
            return false;
        
        SCR_ScenarioFrameworkTaskData frameworkData = SCR_ScenarioFrameworkTaskData.Cast(m_TaskData);
        if (!frameworkData)
        {
            writer.WriteBool(false);
            return true;
        }
        
        writer.WriteBool(true);
        writer.WriteString(frameworkData.m_sTaskExecutionBriefing);
        
        return true;
    }
    
    //------------------------------------------------------------------------------------------------
    override bool RplLoad(ScriptBitReader reader)
    {
        if (!m_TaskData)
            m_TaskData = new SCR_ScenarioFrameworkTaskData();
        
        if (!super.RplLoad(reader))
            return false;
        
        bool hasBriefing;
        reader.ReadBool(hasBriefing);
        if (!hasBriefing)
            return true;
        
        string taskExecutionBriefing;
        reader.ReadString(taskExecutionBriefing);
        
        SCR_ScenarioFrameworkTaskData frameworkData = SCR_ScenarioFrameworkTaskData.Cast(m_TaskData);
        if (!frameworkData)
            return true;
        
        frameworkData.m_sTaskExecutionBriefing = taskExecutionBriefing;
        
        return true;
    }
    
    //------------------------------------------------------------------------------------------------
    override protected void InitializeData()
    {
        if (!m_TaskData)
            m_TaskData = new SCR_ScenarioFrameworkTaskData();
        
        super.InitializeData();
    }
}