SCR_BaseGroup.c

Go to the documentation of this file.

//------------------------------------------------------------------------------------------------
class SCR_BaseGroup : ScriptedSelectionMenuEntry
{   
    protected IEntity m_pOwner;
    protected ref array<ref SCR_BaseGroupEntry> m_aEntries;
    protected int m_iSelectedIndex;
    protected SCR_BaseGroupEntry m_pSelectedEntry;
    protected BaseSelectionMenu m_pSourceMenu;
    
    //------------------------------------------------------------------------------------------------
    protected override bool CanBePerformedScript(IEntity user, BaseSelectionMenu sourceMenu)
    {
        // TODO: Define actual logic?
        if (m_iSelectedIndex < 0)
            return false;
        
        if (m_iSelectedIndex > Count() - 1)
            return false;
        
        return m_aEntries[m_iSelectedIndex].CanBePerformed(user, sourceMenu);
    }
    
    //------------------------------------------------------------------------------------------------
    protected override bool GetEntryNameScript(out string outName)
    {
        if (m_pSelectedEntry)
        {
            auto entryName = m_pSelectedEntry.GetEntryName();
            outName = entryName;
            return true;
        }
        
        outName = "Empty";
        return true;
    }
    
    //------------------------------------------------------------------------------------------------
    protected override UIInfo GetUIInfoScript()
    {
        if (m_pSelectedEntry)
        {
            return m_pSelectedEntry.GetUIInfo();
        }
        
        return null;
    }
    
    //------------------------------------------------------------------------------------------------
    int Count() { return m_aEntries.Count(); }
    
    //------------------------------------------------------------------------------------------------
    void SelectNext()
    {
        auto index = m_iSelectedIndex+1;
        if (index > Count() -1)
            index = 0;
        
        Select(index);
    }
    
    //------------------------------------------------------------------------------------------------
    void SelectPrevious()
    {
        auto index = m_iSelectedIndex-1;
        if (index < 0)
            index = Count() - 1;
        
        Select(index);
    }
    
    //------------------------------------------------------------------------------------------------
    void Select(int index) 
    { 
        // Deselect selected item
        if (index == -1)
        {
            if (m_pSelectedEntry)
                m_pSelectedEntry.OnDonePerform(m_pOwner, m_pSourceMenu);
            
            
            m_pSelectedEntry = null;
            m_iSelectedIndex = -1;
            return;
        }
        
        // Make sure selection is valid and not out of range
        if (index < 0 || index > Count() -1)
            return;
        
        // Try to actually select the entry
        SCR_BaseGroupEntry entry = m_aEntries[index];
        if (entry)
        {
            // Deselect previous entry
            if (m_pSelectedEntry && m_pSelectedEntry != entry) 
            {
                m_pSelectedEntry.OnDonePerform(m_pOwner, m_pSourceMenu);
                m_pSelectedEntry = null;
            }
            
            m_pSelectedEntry = entry;
            m_iSelectedIndex = index;
        }
    }
    
    protected override void OnPerform(IEntity user, BaseSelectionMenu sourceMenu)
    {
        if (m_pSelectedEntry)
        {
            m_pSelectedEntry.Perform(user, sourceMenu);
        }
    }
    
    //------------------------------------------------------------------------------------------------
    IEntity GetOwner() { return m_pOwner; }
    
    //------------------------------------------------------------------------------------------------
    SCR_BaseGroupEntry GetSelectedEntry() { return m_pSelectedEntry; }  
    
    //------------------------------------------------------------------------------------------------
    void SCR_BaseGroup(IEntity owner, array<ref SCR_BaseGroupEntry> entries)
    {
        // Assign the owner entity
        m_pOwner = owner;
        
        // Prepare array and set all the entries
        m_aEntries = new array<ref SCR_BaseGroupEntry>();
        foreach (auto entry : entries)
            m_aEntries.Insert(entry);
    }
};