SCR_AISetting.c

Go to the documentation of this file.

enum SCR_EAISettingOrigin
{
    EDITOR,             // Created by Editor (Game Master) at run time
    SCENARIO,           // Created by scenario framework
    WAYPOINT,           // Placed into waypoint
    COMMANDING,         // AI Commanding
    BEHAVIOR,           // Settings created by AI internally from their behaviors
    DEFAULT             // Settings added to prefabs, as default AI settings
}
 
enum SCR_EAISettingFlags
{
    CREATED_DYNAMICALLY = 1<<0, // Means it was created via script at run time by Create method. It was never part of property.
    
    // These flags below are not mutually exclusive,
    // because as setting gets copied, it will get owned by settings component, while it might originate from waypoint
    SETTINGS_COMPONENT  = 1<<1, // Some settings component owns it
    WAYPOINT            = 1<<2, // Some waypoint owns or owned it
    SCENARIO_FRAMEWORK  = 1<<3  // Some scenario framework container owns or owned this
}

class SCR_AISettingOriginPriorityTable
{
    protected ref array<int> m_aValues; // Index is origin ID, value is priority.
    
    //------------------------------------------------------------------------------------------------
    int GetPriorityForOrigin(SCR_EAISettingOrigin origin)
    {
        if (!m_aValues.IsIndexValid(origin))
            return 0;
        
        return m_aValues[origin];
    }
    
    //---------------------------------------------------------------------------------------------------
    void SCR_AISettingOriginPriorityTable()
    {
        m_aValues = {};
        
        // Init array with settings priorities
        typename t = SCR_EAISettingOrigin;
        int originsCount = Math.ClampInt(t.GetVariableCount(), 0, 32); // Limit array size to some reasonable value
        m_aValues.Resize(originsCount);
        InitPriorities(m_aValues);
    }
    
    //---------------------------------------------------------------------------------------------------
    protected void InitPriorities(array<int> a)
    {
        // Currently idea is to have editor and scenario above commanding, prioritizing mission creator's choice
        a[SCR_EAISettingOrigin.EDITOR]      = 6000;
        a[SCR_EAISettingOrigin.SCENARIO]    = 5000;
        a[SCR_EAISettingOrigin.WAYPOINT]    = 4000;
        a[SCR_EAISettingOrigin.COMMANDING]  = 3000;
        a[SCR_EAISettingOrigin.BEHAVIOR]    = 2000;
        a[SCR_EAISettingOrigin.DEFAULT]     = 1000;
    }
}
 

[BaseContainerProps(visible: false)]
class SCR_AISettingBase
{
    // Special value for settings which do not support action cause.
    // The value is big so that setting is always active regardless of current action cause value.
    const int ACTION_CAUSE_NOT_SUPPORTED = int.MAX;
    
    // Pointer to setting from which this was copied
    protected SCR_AISettingBase m_ParentSetting;
    
    protected SCR_EAISettingOrigin m_eOrigin;
    
    protected SCR_EAISettingFlags m_eFlags;
    
    [SortAttribute()]
    protected int m_iPriority;
    
    // Static table of priority of each origin of settings
    protected static ref SCR_AISettingOriginPriorityTable s_OriginPriorityTable = new SCR_AISettingOriginPriorityTable();
    
    //---------------------------------------------------------------------------------------------------
    int GetPriority()
    {
        return m_iPriority;
    }
    
    //---------------------------------------------------------------------------------------------------
    SCR_EAISettingOrigin GetOrigin()
    {
        return m_eOrigin;
    }
    
    //---------------------------------------------------------------------------------------------------
    SCR_AISettingBase GetParentSetting()
    {
        return m_ParentSetting;
    }
    
    //---------------------------------------------------------------------------------------------------
    SCR_EAISettingFlags GetFlags()
    {
        return m_eFlags;
    }
    
    //---------------------------------------------------------------------------------------------------
    bool HasFlag(SCR_EAISettingFlags f)
    {
        return (m_eFlags & f);
    }
    
    //---------------------------------------------------------------------------------------------------
    int GetMaxActionCause();
    
    
    
    //----------------------------------------------------------------------------------------------------------------------------
    // Internal and protected methods, mostly related to initialization
    
    //---------------------------------------------------------------------------------------------------
    SCR_AISettingBase CreateCopy()
    {
        Managed sManaged = Clone();
        auto s = SCR_AISettingBase.Cast(sManaged);
        return s;
    }
    
    //---------------------------------------------------------------------------------------------------
    void Internal_InitCopyFrom(SCR_AISettingBase from)
    {
        m_ParentSetting = from;
    }
    
    //---------------------------------------------------------------------------------------------------
    protected void Init(SCR_EAISettingOrigin origin)
    {
        m_eFlags |= SCR_EAISettingFlags.CREATED_DYNAMICALLY;
        m_eOrigin = origin;
        m_iPriority = s_OriginPriorityTable.GetPriorityForOrigin(m_eOrigin);
    }
    
    //---------------------------------------------------------------------------------------------------
    void Internal_ConstructedAtProperty(SCR_EAISettingOrigin origin, SCR_EAISettingFlags flagsToSet)
    {
        m_eFlags |= flagsToSet;
        m_eOrigin = origin;
        m_iPriority = s_OriginPriorityTable.GetPriorityForOrigin(m_eOrigin);
    }
    
    //----------------------------------------------------------------------------------------------------------------------------
    void Internal_SetFlag(SCR_EAISettingFlags flagsToSet)
    {
        m_eFlags |= flagsToSet;
    }
    
    //----------------------------------------------------------------------------------------------------------------------------
    // Methods to override in derived classes
    
    //---------------------------------------------------------------------------------------------------
    typename GetCategorizationType()
    {
        return Type();
    }
    
    //---------------------------------------------------------------------------------------------------
    void OnAdded(SCR_AISettingsBaseComponent settingsComp);
    
    //---------------------------------------------------------------------------------------------------
    void OnRemoved(SCR_AISettingsBaseComponent settingsComp);
    
    //---------------------------------------------------------------------------------------------------
    void ApplyEffects(SCR_AISettingsBaseComponent settingsComp);
    
    //---------------------------------------------------------------------------------------------------
    string GetDebugText()
    {
        return string.Empty;
    }
}