SCR_BallisticData.c

Go to the documentation of this file.

class SCR_BallisticData : ScriptAndConfig
{
    static ref array<ref SCR_BallisticData> s_aBallistics;
    static bool s_bWaitingForEndOfTheGame;

    protected ref array<ref array<float>> m_aBallisticValues;
    protected ResourceName m_sProjectilePrefabName;
    protected bool m_bDirectFireMode;
    protected int m_iRangeStep;
    protected float m_fProjectileInitSpeedCoef;
    protected ref map<int, int> m_mDistances;
 
    //------------------------------------------------------------------------------------------------
    int GetNumberOfEntries()
    {
        if (!m_aBallisticValues)
            return 0;
 
        return m_aBallisticValues.Count();
    }
 
    //------------------------------------------------------------------------------------------------
    int GetValues(int id, out array<float> values)
    {
        if (!m_aBallisticValues.IsIndexValid(id))
            return 0;
 
        values = m_aBallisticValues[id];
        return values.Count();
    }
 
 
    //------------------------------------------------------------------------------------------------
    void SetValues(int id, notnull array<float> newValues)
    {
        if (!m_aBallisticValues.IsIndexValid(id))
            return;
 
        m_aBallisticValues[id] = newValues;
    }
 
    //------------------------------------------------------------------------------------------------
    array<float> GetBallisticValuesForClosestRange(int range, out int id = -1)
    {
        if (m_iRangeStep == 0 || !m_aBallisticValues || m_aBallisticValues.IsEmpty())
            return null;
 
        range = Math.Round(range / m_iRangeStep) * m_iRangeStep;
        if (m_mDistances.Contains(range))
            return GetBallisticValuesForRange(range, id);
 
        if (range <= m_aBallisticValues[0][0])
        {
            id = 0;
            return m_aBallisticValues[0];
        }
 
        id = m_aBallisticValues.Count() - 1;
        return m_aBallisticValues[id];
    }
 
    //------------------------------------------------------------------------------------------------
    array<float> GetBallisticValuesForClosestAngle(float angle, out int id = -1, float epsilon = 0.1, float epsilonStep = 2, float maxEpsilon = 1000)
    {
        if (epsilon > maxEpsilon)
        {
            angle = -1;
            id = -1;
            return null;
        }
 
        foreach(int i, array<float> entry : m_aBallisticValues)
        {
            if (float.AlmostEqual(entry[1], angle, epsilon))
            {
                angle = entry[0];
                id = i;
                return entry;
            }
        }
 
        return GetBallisticValuesForClosestAngle(angle, id, epsilon * epsilonStep, epsilonStep, maxEpsilon);
    }
 
    //------------------------------------------------------------------------------------------------
    array<float> GetBallisticValuesForRange(int range, out int id = -1)
    {
        if (!m_mDistances.Contains(range))
            return null;
 
        id = m_mDistances.Get(range);
        return m_aBallisticValues[id];
    }
 
    //------------------------------------------------------------------------------------------------
    ResourceName GetProjectileName()
    {
        return m_sProjectilePrefabName;
    }
 
    //------------------------------------------------------------------------------------------------
    int GetRangeStep()
    {
        return m_iRangeStep;
    }
 
    //------------------------------------------------------------------------------------------------
    float GetProjectileInitSpeedCoef()
    {
        return m_fProjectileInitSpeedCoef;
    }
 
    //------------------------------------------------------------------------------------------------
    bool IsForDirectFireMode()
    {
        return m_bDirectFireMode;
    }
 
    //------------------------------------------------------------------------------------------------
    // constructor
    void SCR_BallisticData(notnull array<ref array<float>> ballisticValues, string projectilePrefab, bool directFireMode, int rangeStep, float speedCoef)
    {
        m_aBallisticValues = ballisticValues;
        if (!m_aBallisticValues && m_aBallisticValues.IsEmpty())
            return;
 
        m_mDistances = new map<int, int>();
        foreach (int i, array<float> ballistics : m_aBallisticValues)
        {
            m_mDistances.Insert(ballistics[0], i);
        }
 
        m_sProjectilePrefabName = projectilePrefab;
        m_bDirectFireMode = directFireMode;
        m_iRangeStep = rangeStep;
        m_fProjectileInitSpeedCoef = speedCoef;
        SubscribeToGameEndEvent();
    }
 
    //------------------------------------------------------------------------------------------------
    static void SubscribeToGameEndEvent()
    {
        if (s_bWaitingForEndOfTheGame)
            return;
 
        SCR_BaseGameMode gameMode = SCR_BaseGameMode.Cast(GetGame().GetGameMode());
        if (!gameMode)
            return;
 
        s_bWaitingForEndOfTheGame = true;
        gameMode.GetOnGameEnd().Insert(ReleaseData);
    }
 
    //------------------------------------------------------------------------------------------------
    protected static void ReleaseData()
    {
        s_aBallistics = null;
        s_bWaitingForEndOfTheGame = false;
        SCR_BaseGameMode gameMode = SCR_BaseGameMode.Cast(GetGame().GetGameMode());
        gameMode.GetOnGameEnd().Remove(ReleaseData);
    }
}