SCR_AutotestSuiteBase.c

Go to the documentation of this file.

[BaseContainerProps(category: "Autotest")]
class SCR_AutotestSuiteBase : TestSuite
{
    //------------------------------------------------------------------------------------------------
    ResourceName GetWorldFile()
    {
        return SCR_AutotestHelper.GetDefaultWorld();
    }
 
    //------------------------------------------------------------------------------------------------
    ResourceName GetWorldSystemsConfigFile()
    {
        return SCR_AutotestHelper.GetDefaultSystemsConfig();
    }
 
    //------------------------------------------------------------------------------------------------
    void Print(string msg, LogLevel level = LogLevel.NORMAL)
    {
        SCR_AutotestHarness.GetLogger().Log(msg, level);
    }
 
    //------------------------------------------------------------------------------------------------
    void PrintFormat(string fmt, string param1 = "", string param2 = "", string param3 = "", LogLevel level = LogLevel.NORMAL)
    {
        SCR_AutotestHarness.GetLogger().Log(string.Format(fmt, param1, param2, param3), level);
    }
 
    //------------------------------------------------------------------------------------------------
    [Step(EStage.Setup)]
    private void Setup_PrintPrelude()
    {
        SCR_AutotestHarness.GetLogger().PrintTestSuitePrelude(this);
    }
 
    //------------------------------------------------------------------------------------------------
    [Step(EStage.Setup)]
    private void Setup_OpenWorld()
    {
        ResourceName world = GetWorldFile();
        ResourceName systemsConfig = GetWorldSystemsConfigFile();
        if (world && !SCR_AutotestHelper.WorldOpenFile(world, systemsConfig))
        {
            string failure = string.Format("Failed to load world: %1, %2", world, systemsConfig);
            SCR_AutotestHarness.GetLogger().Log(failure, level: LogLevel.ERROR);
 
            SetResult(SCR_AutotestResult.AsFailure(failure));
        }
    }
 
    //------------------------------------------------------------------------------------------------
    [Step(EStage.Setup)]
    private bool Setup_AwaitWorld()
    {
        return !GameStateTransitions.IsTransitionRequestedOrInProgress();
    }
 
    //------------------------------------------------------------------------------------------------
    [Step(EStage.Setup)]
    private void Setup_CloseMenus()
    {
        GetGame().GetMenuManager().CloseAllMenus();
    }
 
    //------------------------------------------------------------------------------------------------
    [Step(EStage.TearDown)]
    private void TearDown_PrintEpilogue()
    {
        SCR_AutotestHarness.GetLogger().PrintTestSuiteEpilogue(this);
    }
}
 
#ifdef MODULE_AUTOTEST
// HACK: prevents script compilation from sealing methods by overriding them in any class
// fixes the issue with not being able to override these methods in different script modules (Autotest/)
sealed class SCR_Hack_AutotestSuiteBase : SCR_AutotestSuiteBase
{
    override ResourceName GetWorldFile();
    override ResourceName GetWorldSystemsConfigFile();
}
#endif