SCR_BaseRadialCommand.c

Go to the documentation of this file.

[BaseContainerProps("", "Entry of one command"), SCR_BaseGroupCommandTitleField("m_sCommandName")]
class SCR_BaseRadialCommand
{
    [Attribute("", UIWidgets.EditBox, "Unique name of the command")]
    protected string m_sCommandName;
    
    [Attribute("", UIWidgets.EditBox, "Display name of the command, in future will replace the one in commanding menu conf")]
    protected string m_sCommandDisplayName;
    
    [Attribute("{2EFEA2AF1F38E7F0}UI/Textures/Icons/icons_wrapperUI-64.imageset", UIWidgets.ResourceNamePicker, "Imageset source for display icon" )]
    protected ResourceName m_sImageset;
    
    [Attribute("", UIWidgets.EditBox, "Name of the icon associated to the command, taken from appropriate imageset set in the radial menu" )]
    protected string m_sIconName;
 
    [Attribute(SCR_ECharacterRank.INVALID.ToString(), UIWidgets.ComboBox, desc: "Rank that is requried in order to use this command.\nINVALID == no requirement", enums: ParamEnumArray.FromEnum(SCR_ECharacterRank))]
    protected SCR_ECharacterRank m_eRequiredRank;
 
    protected LocalizedString m_sCannotPerformReason;
    protected LocalizedString m_sCannotExecuteReason;
 
    protected static const LocalizedString CANNOT_PERFORM_RANK_TOO_LOW  = "#AR-Commanding_CannotPefrorm_RankTooLow";
    protected static const LocalizedString CANNOT_EXECUTE_SOLDIER_NA    = "#AR-Commanding_CannotExecute_SoldierNotAvailable";
 
    //------------------------------------------------------------------------------------------------
    // Returns true if the command was executed succesfully, false otherwise.
    bool Execute(IEntity cursorTarget, IEntity target, vector targetPosition, int playerID, bool isClient)
    {
        return true;
    }
    
    //------------------------------------------------------------------------------------------------
    void VisualizeCommand(vector targetPosition);
    
    //------------------------------------------------------------------------------------------------
    void VisualizeCommandPreview(vector targetPosition);
    
    //------------------------------------------------------------------------------------------------
    string GetIconName()
    {
        return m_sIconName;
    }
    
    //------------------------------------------------------------------------------------------------
    string GetCommandDisplayName()
    {
        return m_sCommandDisplayName;
    }
    
    //------------------------------------------------------------------------------------------------
    ResourceName GetIconImageset()
    {
        return m_sImageset;
    }
        
    //------------------------------------------------------------------------------------------------
    string GetCommandName()
    {
        return m_sCommandName;
    }
            
    //------------------------------------------------------------------------------------------------
    bool CanRoleShow()
    {
        return true;
    }
    
    //------------------------------------------------------------------------------------------------
    bool CanBeShownInCurrentLifeState()
    {
        return true;
    }
    
    //------------------------------------------------------------------------------------------------
    bool CanBeShown()
    {
        return true;
    }
    
    //------------------------------------------------------------------------------------------------
    bool CanShowOnMap()
    {
        return true;
    }
    
    //------------------------------------------------------------------------------------------------  
    bool CanBePerformed(notnull SCR_ChimeraCharacter user)
    {
        if (m_eRequiredRank == SCR_ECharacterRank.INVALID)
            return true;
 
        if (!SCR_XPHandlerComponent.IsXpSystemEnabled())
            return true;
 
        SCR_ECharacterRank currentRank = SCR_CharacterRankComponent.GetCharacterRank(user);
        if (currentRank < m_eRequiredRank)
        {
            SCR_Faction userFaction = SCR_Faction.Cast(user.GetFaction());
            if (!userFaction)
                return false;
 
            SCR_RankContainer userRanks = userFaction.GetRanks();
            string requiredRankName = userRanks.GetRankName(m_eRequiredRank);
 
            if (requiredRankName == string.Empty) // If we dont define this rank in this faction, we will attempt to get the next one that would qualify.
                requiredRankName = userRanks.GetRankName(userRanks.GetNextRank(m_eRequiredRank));
 
            string currentRankName = userRanks.GetRankName(currentRank);
            SetCannotPerformReason(WidgetManager.Translate(CANNOT_PERFORM_RANK_TOO_LOW, requiredRankName, currentRankName));
            return false;
        }
 
        return true;
    }
    
    //------------------------------------------------------------------------------------------------  
    bool CanBeExecuted(IEntity target)
    {
        return true;
    }
    
    //------------------------------------------------------------------------------------------------
    protected void SetCannotExecuteReason(LocalizedString newReason)
    {
        m_sCannotExecuteReason = newReason;
    }
    
    //------------------------------------------------------------------------------------------------
    protected void SetCannotPerformReason(LocalizedString newReason)
    {
        m_sCannotPerformReason = newReason;
    }
    
    //------------------------------------------------------------------------------------------------
    LocalizedString GetCannotExecuteReason()
    {
        return m_sCannotExecuteReason;
    }
    
    //------------------------------------------------------------------------------------------------
    LocalizedString GetCannotPerformReason()
    {
        return m_sCannotPerformReason;
    }
}