SCR_ExtendedIdentity.c

Go to the documentation of this file.

[BaseContainerProps()]
class SCR_ExtendedIdentity
{
    [Attribute("-1", desc: "Leave -1 to auto assign.", params: "-1 inf 1")]
    protected int m_iAge;
    
    [Attribute("-1", desc: "Day character is born or entity is created. Leave -1 to auto assign.", params: "-1 31 1")]
    protected int m_iDayOfCreation;
    
    [Attribute("-1", desc:  "Month character is born or entity is created. Leave -1 to auto assign.", params: "-1 12 1")]
    protected int m_iMonthOfCreation;
    
    [Attribute(desc: "Original faction of entity. Leave empty to auto assign (Uses AIGroup or FactionAffiliationComponent to get faction). This is used to get random place of creation/birth within the faction.")]
    protected string m_sFactionOfOriginKey;
    
    [Attribute(desc: "Birth or creation place. Leave empty to auto assign.")]
    protected ref SCR_UIInfo m_PlaceOfOrigin;
    
    protected int m_iFactionOfOriginIndex = -1;
    protected int m_iPlaceOfOriginIndex = -1;
    
    //------------------------------------------------------------------------------------------------
    void SetAge(int age)
    {
        m_iAge = age;
    }
    
    //------------------------------------------------------------------------------------------------
    int GetAge()
    {
        return m_iAge;
    }
    
    //------------------------------------------------------------------------------------------------
    void SetDayOfCreation(int day)
    {
        m_iDayOfCreation = day;
    }
    
    //------------------------------------------------------------------------------------------------
    int GetDayOfCreation()
    {
        return m_iDayOfCreation;
    }
    
    //------------------------------------------------------------------------------------------------
    void SetMonthOfCreation(int month)
    {
        m_iMonthOfCreation = month;
    }
    
    //------------------------------------------------------------------------------------------------
    int GetMonthOfCreation()
    {
        return m_iMonthOfCreation;
    }
    
    //------------------------------------------------------------------------------------------------
    void SetFactionOfOrigin(string factionKey)
    {
        m_sFactionOfOriginKey = factionKey.Trim();
        
        FactionManager factionManager = GetGame().GetFactionManager();
        if (!factionManager)
            return;
        
        Faction faction = factionManager.GetFactionByKey(m_sFactionOfOriginKey);
        if (!faction)
            return;
        
        m_iFactionOfOriginIndex = factionManager.GetFactionIndex(faction);
    }
    
    //------------------------------------------------------------------------------------------------
    void SetFactionOfOrigin(int factionIndex)
    {
        m_iFactionOfOriginIndex = factionIndex;
        
        FactionManager factionManager = GetGame().GetFactionManager();
        if (!factionManager)
            return;
        
        Faction faction = factionManager.GetFactionByIndex(m_iFactionOfOriginIndex);
        if (!faction)
            return;
        
        m_sFactionOfOriginKey = faction.GetFactionKey();
    }
    
    //------------------------------------------------------------------------------------------------
    string GetFactionOfOriginKey()
    {
        //~ Set if not yet set 
        if (SCR_StringHelper.IsEmptyOrWhiteSpace(m_sFactionOfOriginKey) && m_iFactionOfOriginIndex > -1)
            SetFactionOfOrigin(m_iFactionOfOriginIndex);
    
        return m_sFactionOfOriginKey.Trim();
    }
    
    //------------------------------------------------------------------------------------------------
    int GetFactionOfOriginIndex()
    {
        //~ Set if not yet set
        if (m_iFactionOfOriginIndex <= -1 && !SCR_StringHelper.IsEmptyOrWhiteSpace(m_sFactionOfOriginKey))
            SetFactionOfOrigin(m_sFactionOfOriginKey);
        
        return m_iFactionOfOriginIndex;
    }
    
    //------------------------------------------------------------------------------------------------
    void SetPlaceOfOrigin(SCR_UIInfo place, bool isOverwrite)
    {
        m_PlaceOfOrigin = place;
        
        if (isOverwrite)
            m_iPlaceOfOriginIndex = -1;
    }
    
    //------------------------------------------------------------------------------------------------
    void SetPlaceOfOriginIndex(int index)
    {       
        m_iPlaceOfOriginIndex = index;
        
        if (index < 0)
            return;
        
        int factionOfOrigin = GetFactionOfOriginIndex();
        if (factionOfOrigin < 0)
            return;
        
        FactionManager factionManager = GetGame().GetFactionManager();
        if (!factionManager)
            return;
        
        SCR_Faction scrFaction = SCR_Faction.Cast(factionManager.GetFactionByIndex(factionOfOrigin));
        if (!scrFaction)
            return;
        
        SCR_FactionHomeTerritoryConfig territory = scrFaction.GetFactionHomeTerritoryConfig();
        if (!territory)
            return;
        
        SCR_UIInfo uinfo = territory.GetHomeTerritoryUIInfo(m_iPlaceOfOriginIndex);
        if (!uinfo)
            return;
        
        SetPlaceOfOrigin(uinfo, false);
    }
    
    //------------------------------------------------------------------------------------------------
    SCR_UIInfo GetPlaceOfOriginUIInfo()
    {
        return m_PlaceOfOrigin;
    }
    
    //------------------------------------------------------------------------------------------------
    int GetPlaceOfOriginIndex()
    {
        return m_iPlaceOfOriginIndex;
    }
}