SCR_ProjectileWindTable.c

Go to the documentation of this file.

[BaseContainerProps(configRoot: true)]
class SCR_ProjectileWindTable
{
    [Attribute(desc: "Data")]
    protected ref array<ref SCR_ProjectileWindData> m_aData;
 
    //------------------------------------------------------------------------------------------------
    static SCR_ProjectileWindTable GetProjectileWindageData(notnull IEntity projectile)
    {
        ProjectileMoveComponent pmc = ProjectileMoveComponent.Cast(projectile.FindComponent(ProjectileMoveComponent));
        if (!pmc)
            return null;
 
        ProjectileMoveComponentClass data = ProjectileMoveComponentClass.Cast(pmc.GetComponentData(projectile));
        ResourceName rn = data.GetProjectileWindTable();
        if (rn.IsEmpty())
            return null;
 
        Resource res = BaseContainerTools.LoadContainer(rn);
        if (!res.IsValid())
            return null;
 
        BaseContainer container = res.GetResource().ToBaseContainer();
        if (!container)
            return null;
 
        return SCR_ProjectileWindTable.Cast(BaseContainerTools.CreateInstanceFromContainer(container));
    }
 
    //------------------------------------------------------------------------------------------------
    static SCR_ProjectileWindTable GetProjectileWindageData(ResourceName projectileResource)
    {
        Resource res = Resource.Load(projectileResource);
        if (!res.IsValid())
            return null;
 
        BaseResourceObject resObject = res.GetResource();
        if (!resObject)
            return null;
 
        IEntitySource projectileEntitySrc = resObject.ToEntitySource();
        if (!projectileEntitySrc)
            return null;
 
        return GetProjectileWindageData(projectileEntitySrc);
    }
 
    //------------------------------------------------------------------------------------------------
    static SCR_ProjectileWindTable GetProjectileWindageData(notnull IEntitySource projectileEntitySrc)
    {
        ResourceName rn;
        IEntityComponentSource componentSrc;
        for (int i, componentsCount = projectileEntitySrc.GetComponentCount(); i < componentsCount; i++)
        {
            componentSrc = projectileEntitySrc.GetComponent(i);
            if (!componentSrc)
                continue;
 
            if (!componentSrc.GetClassName().ToType().IsInherited(ProjectileMoveComponent))
                continue;
 
            componentSrc.Get("ProjectileWindTableConfig", rn);
            break;
        }
 
        if (rn.IsEmpty())
            return null;
 
        Resource res = BaseContainerTools.LoadContainer(rn);
        if (!res.IsValid())
            return null;
 
        BaseContainer container = res.GetResource().ToBaseContainer();
        if (!container)
            return null;
 
        return SCR_ProjectileWindTable.Cast(BaseContainerTools.CreateInstanceFromContainer(container));
    }
 
    //------------------------------------------------------------------------------------------------
    array<float> GetDataByAngleDeg(float angle, float windSpeed, float initSpeedCoef = 1)
    {
        angle = SCR_Math.ConvertToRadians(angle, SCR_EOpticsAngleUnits.DEGREES);
        return GetDataByAngle(angle, windSpeed, initSpeedCoef);
    }
 
    //------------------------------------------------------------------------------------------------
    array<float> GetDataByAngle(float angle, float windSpeed = 10, float initSpeedCoef = 1)
    {
        foreach (SCR_ProjectileWindData data : m_aData)
        {
            if (initSpeedCoef != data.GetInitSpeedCoef())
                continue;
 
            if (windSpeed != data.GetWindSpeed())
                continue;
 
            return data.GetDataByAngle(angle);
        }
 
        return null;
    }
 
    //------------------------------------------------------------------------------------------------
    array<float> GetDataByDisance(float distance, bool directFire, float windSpeed, float initSpeedCoef = 1)
    {
        foreach (SCR_ProjectileWindData data : m_aData)
        {
            if (initSpeedCoef != data.GetInitSpeedCoef())
                continue;
 
            if (windSpeed != data.GetWindSpeed())
                continue;
 
            return data.GetDataByDisance(distance, directFire);
        }
 
        return null;
    }
 
    //------------------------------------------------------------------------------------------------
    // constructor
    void SCR_ProjectileWindTable(array<ref SCR_ProjectileWindData> data)
    {
        if (data)
            m_aData = data;
    }
}