SCR_ScenarioFrameworkCharacterInVehicleCondition.c

Go to the documentation of this file.

[BaseContainerProps()]
class SCR_ScenarioFrameworkCharacterInVehicleCondition : SCR_ScenarioFrameworkActivationConditionBase
{
    [Attribute(desc: "Entity to check.")]
    ref SCR_ScenarioFrameworkGet m_Getter;
 
    //------------------------------------------------------------------------------------------------
    override bool Init(IEntity entity)
    {
        // Here you can debug specific Condition instance.
        // This can be also adjusted during runtime via Debug Menu > ScenarioFramework > Condition Inspector
        if (m_bDebug)
            Print("[SCR_ScenarioFrameworkCharacterInVehicleCondition.Init] debug line (" + __FILE__ + " L" + __LINE__ + ")", LogLevel.WARNING);
        
        if (!m_Getter)
            return false;
 
        SCR_ScenarioFrameworkParam<IEntity> entityWrapper = SCR_ScenarioFrameworkParam<IEntity>.Cast(m_Getter.Get());
        if (!entityWrapper)
        {
            SCR_ScenarioFrameworkParam<array<IEntity>> entityArrayWrapper = SCR_ScenarioFrameworkParam<array<IEntity>>.Cast(m_Getter.Get());
            if (!entityArrayWrapper)
            {
                PrintFormat("ScenarioFramework Condition: Issue with Getter detected for condition %1.", this, level: LogLevel.ERROR);
                return false;
            }
 
            array<IEntity> entities = entityArrayWrapper.GetValue();
 
            if (entities.IsEmpty())
            {
                PrintFormat("ScenarioFramework Condition: Array Getter for %1 has no elements to work with.", this, level: LogLevel.ERROR);
                return false;
            }
 
            foreach (IEntity ent : entities)
            {
                if (!EvaluateInVehiclePresence(ent))
                    return false;
            }
 
            return true;
        }
 
        IEntity wrappedEntity = entityWrapper.GetValue();
        if (!wrappedEntity)
        {
            Print(string.Format("ScenarioFramework Condition: Entity not found for condition %1.", this), LogLevel.ERROR);
            return false;
        }
        
        return EvaluateInVehiclePresence(wrappedEntity);
    }
    
    //------------------------------------------------------------------------------------------------
    bool EvaluateInVehiclePresence(notnull IEntity ent)
    {
        SCR_ChimeraCharacter character = SCR_ChimeraCharacter.Cast(ent);
        if (!character)
            return false;
        
        IEntity vehicle;
        SCR_CompartmentAccessComponent compartmentAccessComponent = SCR_CompartmentAccessComponent.Cast(ent.FindComponent(SCR_CompartmentAccessComponent));
        if (!compartmentAccessComponent)
            false;
        
        return compartmentAccessComponent.GetVehicle();
    }
}