SCR_CharacterHelper.c

Go to the documentation of this file.

class SCR_CharacterHelper
{
    //------------------------------------------------------------------------------------------------
    static IEntity GetPlayer()
    {
        return EntityUtils.GetPlayer();
    }
 
    //------------------------------------------------------------------------------------------------
    // unused
    static bool IsPlayer(IEntity entity)
    {
        return entity && entity == EntityUtils.GetPlayer();
    }
    
    //------------------------------------------------------------------------------------------------
    static SCR_ECharacterControlType GetPlayerControlType(int playerID)
    {
        if (playerID <= 0)
        {
            Print("'SCR_EntityHelper.GetPlayerControlType()' Given player id is not valid", LogLevel.WARNING);
            return SCR_ECharacterControlType.UNKNOWN;
        }
        
        //~ If character is on the admin list
        SCR_PlayerListedAdminManagerComponent adminListManager = SCR_PlayerListedAdminManagerComponent.GetInstance();
        if (adminListManager && adminListManager.IsPlayerOnAdminList(playerID))
            return SCR_ECharacterControlType.UNLIMITED_EDITOR;
        
        //~ If character is an Admin or Game Master
        PlayerManager playerManager = GetGame().GetPlayerManager();
        if (playerManager && (playerManager.HasPlayerRole(playerID, EPlayerRole.GAME_MASTER) || playerManager.HasPlayerRole(playerID, EPlayerRole.ADMINISTRATOR || playerManager.HasPlayerRole(playerID, EPlayerRole.SESSION_ADMINISTRATOR))))
            return SCR_ECharacterControlType.UNLIMITED_EDITOR;
        
        return SCR_ECharacterControlType.PLAYER;
    }
    
    //------------------------------------------------------------------------------------------------
    static SCR_ECharacterControlType GetCharacterControlType(IEntity entity)
    {
        //~ No entity given
        if (!entity)
        {
            Print("'SCR_EntityHelper.GetCharacterControlType()' Given entity is null", LogLevel.WARNING);
            return SCR_ECharacterControlType.UNKNOWN;
        }
        
        //~ Entity is not a character
        ChimeraCharacter character = ChimeraCharacter.Cast(entity);
        if (!character)
        {
            Print("'SCR_EntityHelper.GetCharacterControlType()' Given entity is not a character nor a vehicle so unknown type is returned", LogLevel.WARNING);
            return SCR_ECharacterControlType.UNKNOWN;
        }
 
        //~ Character is a player
        int playerID = SCR_PossessingManagerComponent.GetPlayerIdFromControlledEntity(character);
        if (playerID > 0)
        {
            //~ If character is possesed
            SCR_PossessingManagerComponent possessingManager = SCR_PossessingManagerComponent.GetInstance();
            if (possessingManager.IsPossessing(playerID))
            {
                if (possessingManager.GetPossessedEntity(playerID) == entity)
                    return SCR_ECharacterControlType.POSSESSED_AI;
            }
                
            //~ If character is on the admin list
            SCR_PlayerListedAdminManagerComponent adminListManager = SCR_PlayerListedAdminManagerComponent.GetInstance();
            if (adminListManager && adminListManager.IsPlayerOnAdminList(playerID))
                return SCR_ECharacterControlType.UNLIMITED_EDITOR;
            
            //~ If character is an Admin or Game Master
            PlayerManager playerManager = GetGame().GetPlayerManager();
            if (playerManager && (playerManager.HasPlayerRole(playerID, EPlayerRole.GAME_MASTER) || playerManager.HasPlayerRole(playerID, EPlayerRole.ADMINISTRATOR || playerManager.HasPlayerRole(playerID, EPlayerRole.SESSION_ADMINISTRATOR))))
                return SCR_ECharacterControlType.UNLIMITED_EDITOR;
            
            return SCR_ECharacterControlType.PLAYER;
        }
        
        //~ Character is an AI
        return SCR_ECharacterControlType.AI;
    }
 
    //------------------------------------------------------------------------------------------------
    // unused
    static bool IsAPlayer(IEntity entity)
    {
        return entity && EntityUtils.IsPlayer(entity);
    }
 
    //------------------------------------------------------------------------------------------------
    static bool IsPlayerOrAIOwner(notnull ChimeraCharacter character, out bool isAi = false)
    {
        isAi = false;
        if (SCR_PlayerController.GetLocalControlledEntity() == character)
            return true;//do this first as IsPlayer fetches all players
 
        if (EntityUtils.IsPlayer(character))
            return false;
 
        isAi = true;
        //if this is ai then make sure that we have the authority over this entity
        RplComponent charRplComp = character.GetRplComponent();
        if (charRplComp && !charRplComp.IsOwner())
            return false;
 
        return true;
    }
}