SCR_ItemOutfitFactionComponent.c

Go to the documentation of this file.

[ComponentEditorProps(category: "GameScripted/Inventory", description: "")]
class SCR_ItemOutfitFactionComponentClass : ScriptComponentClass
{
}
 
[BaseContainerProps(), SCR_BaseContainerTitleFieldWithValue("m_AffiliatedFactionKey", "m_iOutfitFactionValue", "%1: %2", "10")]
class SCR_OutfitFactionData
{
    [Attribute(desc: "Needs to be unique")]
    protected FactionKey m_AffiliatedFactionKey;
    
    [Attribute("10", desc: "0 value means it is ignored", params: "0 inf")]
    protected int m_iOutfitFactionValue;
    
    protected Faction m_AffiliatedFaction;
    
    //------------------------------------------------------------------------------------------------
    bool Init(notnull FactionManager factionManager)
    {       
        m_AffiliatedFaction = factionManager.GetFactionByKey(m_AffiliatedFactionKey);
        if (!m_AffiliatedFaction)
            return false;
        
        return m_iOutfitFactionValue > 0;
    }
    
    //------------------------------------------------------------------------------------------------
    FactionKey GetAffiliatedFactionKey()
    {
        return m_AffiliatedFactionKey;
    }
    
    //------------------------------------------------------------------------------------------------
    int GetOutfitFactionValue()
    {
        return m_iOutfitFactionValue;
    }
    
    //------------------------------------------------------------------------------------------------
    Faction GetAffiliatedFaction()
    {
        return m_AffiliatedFaction;
    }
}
 
[BaseContainerProps()]
class SCR_OutfitFactionDataHolder
{
    [Attribute()]
    protected ref array<ref SCR_OutfitFactionData> m_aOutfitFactionData;
    
    //------------------------------------------------------------------------------------------------
    void Init(notnull FactionManager factionManager)
    {
        //~ Clear any invalid entries
        for (int i = m_aOutfitFactionData.Count() - 1; i >= 0; i--)
        {
            //~ Init. If failed remove from init
            if (!m_aOutfitFactionData[i].Init(factionManager))
            {
                m_aOutfitFactionData.RemoveOrdered(i);
                continue;
            }
        }
    }
    
    //------------------------------------------------------------------------------------------------
    int GetOutfitFactionDataArrayCount()
    {
        return m_aOutfitFactionData.Count();
    } 
    
    //------------------------------------------------------------------------------------------------

    int GetOutfitFactionDataArray(out notnull array<SCR_OutfitFactionData> outfitDataArray)
    {
        outfitDataArray.Clear();
        
        foreach(SCR_OutfitFactionData data : m_aOutfitFactionData)
        {
            outfitDataArray.Insert(data);
        }
        
        return outfitDataArray.Count();
    }
    
    //------------------------------------------------------------------------------------------------
    SCR_OutfitFactionData GetOutfitFactionData(FactionKey faction)
    {
        if (faction.IsEmpty())
            return null;
        
        foreach (SCR_OutfitFactionData data : m_aOutfitFactionData)
        {
            if (data.GetOutfitFactionValue() <= 0)
                continue;
            
            if (data.GetAffiliatedFactionKey() == faction)
                return data;
        }
        
        return null;
    }
    
    //------------------------------------------------------------------------------------------------
    SCR_OutfitFactionData GetOutfitFactionData(notnull Faction faction)
    {       
        foreach (SCR_OutfitFactionData data : m_aOutfitFactionData)
        {
            if (data.GetOutfitFactionValue() <= 0)
                continue;
            
            if (data.GetAffiliatedFaction() == faction)
                return data;
        }
        
        return null;
    }
}
 
class SCR_ItemOutfitFactionComponent : ScriptComponent
{
    [Attribute()]
    protected ref SCR_OutfitFactionDataHolder m_OutfitDataHolder;
    
    protected bool m_bInitCalled;
    
    //------------------------------------------------------------------------------------------------
    bool IsValid()
    {
        return m_OutfitDataHolder && m_OutfitDataHolder.GetOutfitFactionDataArrayCount() > 0;
    }
    
    //------------------------------------------------------------------------------------------------
    int GetOutfitFactionDataArray(out notnull array<SCR_OutfitFactionData> outfitValues)
    {
        if (!m_OutfitDataHolder)
            return 0;
        
        array<SCR_OutfitFactionData> outfitDataArray = {};
        m_OutfitDataHolder.GetOutfitFactionDataArray(outfitDataArray);
        
        foreach(SCR_OutfitFactionData data : outfitDataArray)
        {
            outfitValues.Insert(data);
        }
        
        return outfitValues.Count();
    }
    
    //------------------------------------------------------------------------------------------------
    int GetOutfitValueOfFaction(notnull Faction faction)
    {
        if (!m_OutfitDataHolder)
            return 0;
        
        array<SCR_OutfitFactionData> outfitDataArray = {};
        m_OutfitDataHolder.GetOutfitFactionDataArray(outfitDataArray);
        
        foreach(SCR_OutfitFactionData data : outfitDataArray)
        {
            if (data.GetAffiliatedFactionKey() == faction.GetFactionKey())
                return data.GetOutfitFactionValue();
        }
        
        return 0;
    }
    
    //------------------------------------------------------------------------------------------------
    void OnAddedToSlot(notnull SCR_CharacterFactionAffiliationComponent characterFactionAffiliationComponent, bool updateFaction = true)
    {       
        if (!IsValid())
            return;
        
        if (!m_bInitCalled)
            Init();
        
        characterFactionAffiliationComponent.AddFactionOutfitValue(m_OutfitDataHolder, updateFaction);
    }
    
    //------------------------------------------------------------------------------------------------
    void OnRemovedFromSlot(notnull SCR_CharacterFactionAffiliationComponent characterFactionAffiliationComponent, bool updateFaction = true)
    {
        if (!IsValid())
            return;
        
        if (!m_bInitCalled)
            Init();
        
        characterFactionAffiliationComponent.RemoveFactionOutfitValue(m_OutfitDataHolder, updateFaction);
    }
    
    //------------------------------------------------------------------------------------------------
    protected void Init()
    {
        if (m_bInitCalled)
            return;
        
        m_bInitCalled = true;
        
        if (!m_OutfitDataHolder)
            return;
        
        FactionManager factionManager = GetGame().GetFactionManager();
        if (!factionManager)
        {
            m_OutfitDataHolder = null;
            return;
        }
            
        m_OutfitDataHolder.Init(factionManager);
    }
    
    //------------------------------------------------------------------------------------------------
    override void EOnInit(IEntity owner)
    {
        Init();
    }
    
    //------------------------------------------------------------------------------------------------
    override void OnPostInit(IEntity owner)
    {
        if (SCR_Global.IsEditMode())
            return;
        
        SetEventMask(owner, EntityEvent.INIT);
    }
}