SCR_CharacterSlowdownEasingSystem.c

Go to the documentation of this file.

class SCR_CharacterSlowdownEasingSystem : GameSystem
{
    protected ref array<SCR_ChimeraCharacter> m_aCharacters = {};
    
    [Attribute(defvalue: "3", desc: "Transition Strength", params: "0 inf 0.01")]
    protected float m_fTransitionStrength;
 
    //------------------------------------------------------------------------------------------------
    override static void InitInfo(WorldSystemInfo outInfo)
    {
        outInfo.SetAbstract(false);
        outInfo.SetLocation(WorldSystemLocation.Both);
        outInfo.AddPoint(WorldSystemPoint.FixedFrame);
    }
        
    //------------------------------------------------------------------------------------------------
    protected override void OnInit()
    {
        Enable(false);
    }
    
    //------------------------------------------------------------------------------------------------
    protected override void OnUpdatePoint(WorldUpdatePointArgs args)
    {
        float dt = args.GetTimeSliceSeconds();
        
        for (int idx = m_aCharacters.Count() - 1; idx >= 0; idx--)
        {
            SCR_ChimeraCharacter character = m_aCharacters[idx];
            if (!character)
            {
                m_aCharacters.Remove(idx);
                continue;           
            }
            
            character.UpdateSlowdown(dt * m_fTransitionStrength);
        }
    }
    
    //------------------------------------------------------------------------------------------------
    void Register(notnull SCR_ChimeraCharacter character)
    {
        if (!m_aCharacters.Contains(character))
            m_aCharacters.Insert(character);
        
        if (!IsEnabled())
            Enable(true);
    }
 
    //------------------------------------------------------------------------------------------------
    void Unregister(notnull SCR_ChimeraCharacter character)
    {
        if (m_aCharacters.Contains(character))
            m_aCharacters.RemoveItem(character);
        
        if (m_aCharacters.IsEmpty())
            Enable(false);
    }
}