SCR_RemoveAIGroupCommand.c

Go to the documentation of this file.

//------------------------------------------------------------------------------------------------
[BaseContainerProps(), SCR_BaseGroupCommandTitleField("m_sCommandName")]
class SCR_RemoveAIGroupCommand : SCR_BaseGroupCommand
{
    //------------------------------------------------------------------------------------------------
    override bool Execute(IEntity cursorTarget, IEntity target, vector targetPosition, int playerID, bool isClient)
    {
        if (isClient)
        {
            //place to place a logic that would be executed for other players
            return true;
        }       
        
        SCR_PlayerController playerController =SCR_PlayerController.Cast(GetGame().GetPlayerManager().GetPlayerController(playerID));
        if (!playerController)
            return false;
        
        SCR_PlayerControllerGroupComponent groupController = SCR_PlayerControllerGroupComponent.Cast(playerController.FindComponent(SCR_PlayerControllerGroupComponent));
        if (!groupController)
            return false;
        
        SCR_ChimeraCharacter character = SCR_ChimeraCharacter.Cast(cursorTarget);
        if (!character)
            return false;
        
        if (GetGame().GetPlayerManager().GetPlayerIdFromControlledEntity(character) == 0)
            groupController.RequestRemoveAgent(character, playerID);
        
        return true;
    }
    
    //------------------------------------------------------------------------------------------------
    override bool CanBeShown()
    {
        if (!CanBeShownInCurrentLifeState())
            return false;
        
        PlayerCamera camera = GetGame().GetPlayerController().GetPlayerCamera();
        if (!camera)
            return false;
        
        IEntity cursorTarget = camera.GetCursorTarget();
        SCR_ChimeraCharacter character = SCR_ChimeraCharacter.Cast(cursorTarget);
        if (!character)
            return false;
        
        SCR_PlayerController playerController = SCR_PlayerController.Cast(GetGame().GetPlayerController());
        if (!playerController)
            return false;
        
        SCR_GroupsManagerComponent groupManager = SCR_GroupsManagerComponent.GetInstance();
        if (!groupManager)
            return false;
        
        SCR_PlayerControllerGroupComponent groupController = SCR_PlayerControllerGroupComponent.GetLocalPlayerControllerGroupComponent();
        if (!groupController)
            return false;
        
        if (!CanRoleShow())
            return false;
        
        if (character.GetFaction() != playerController.GetLocalControlledEntityFaction())
            return false;
        
        int playerID = GetGame().GetPlayerController().GetPlayerId();
        SCR_AIGroup playerGroup = groupManager.GetPlayerGroup(playerID);
        
        return playerGroup.IsAIControlledCharacterMember(character);
    }
}