SCR_ScenarioFrameworkActionChangeTaskState.c

Go to the documentation of this file.

[BaseContainerProps(), SCR_ContainerActionTitle()]
class SCR_ScenarioFrameworkActionChangeTaskState : SCR_ScenarioFrameworkActionBase
{
    [Attribute(desc: "Which task to work with - Use GetTask")]
    ref SCR_ScenarioFrameworkGetTask        m_Getter;
 
    [Attribute(defvalue: SCR_ETaskState.COMPLETED.ToString(), UIWidgets.ComboBox, "Task state", "", ParamEnumArray.FromEnum(SCR_ETaskState))]
    SCR_ETaskState m_eTaskState;
 
    //------------------------------------------------------------------------------------------------
    override void OnActivate(IEntity object)
    {
        if (!CanActivate())
            return;
 
        if (!m_Getter)
        {
            Print(string.Format("ScenarioFramework Action: Getter not found for Action %1.", this), LogLevel.ERROR);
            return;
        }
 
        SCR_ScenarioFrameworkParam<IEntity> entityWrapper = SCR_ScenarioFrameworkParam<IEntity>.Cast(m_Getter.Get());
        if (!entityWrapper)
        {
            Print(string.Format("ScenarioFramework Action: Issue with Getter detected for Action %1.", this), LogLevel.ERROR);
            return;
        }
 
        SCR_ScenarioFrameworkTask task = SCR_ScenarioFrameworkTask.Cast(entityWrapper.GetValue());
        if (!task)
        {
            if (object)
                    Print(string.Format("ScenarioFramework Action: Task not found for Action %1 attached on %2.", this, object.GetName()), LogLevel.ERROR);
                else
                    Print(string.Format("ScenarioFramework Action: Task not found for Action %1.", this), LogLevel.ERROR);
 
            return;
        }
 
        SCR_TaskSystem taskSystem = SCR_TaskSystem.GetInstance();
        if (!taskSystem)
            return;
        
        SCR_ScenarioFrameworkLayerTask layerTask = task.GetLayerTask();
        if (!layerTask)
            return;
        
        layerTask.ProcessLayerTaskState(m_eTaskState);
    }
}