SCR_AdditionalDeployablePart.c

Go to the documentation of this file.

class SCR_AdditionalDeployablePart : ScriptAndConfig
{
    [Attribute(uiwidget: UIWidgets.ResourcePickerThumbnail, desc: "Prefab which is going to be required in order to deploy the main entity", params: "et")]
    protected ResourceName m_sPrefab;
 
    [Attribute(defvalue: "1", desc: "How many instances of this prefab should be spawned", params: "1 inf")]
    protected int m_iNumberOfPrefabs;
 
    //------------------------------------------------------------------------------------------------
    ResourceName GetPrefab()
    {
        return m_sPrefab;
    }
 
    //------------------------------------------------------------------------------------------------
    bool SpawnPrefabs(int authorPlayerId, IEntity user, notnull EntitySpawnParams params)
    {
        Resource resource = Resource.Load(m_sPrefab);
        if (!resource.IsValid())
        {
            Print("[SCR_AdditionalDeployablePart.SpawnPrefabs] => Failed to load the resource from m_sPrefab = " + m_sPrefab, LogLevel.ERROR);
            return false;
        }
 
        vector spawnedMat[4];
        IEntity spawnedEntity;
        InventoryItemComponent spawnedIIC;
        int numberOfSuccesfullySpawnedEnts;
        for(int i; i < m_iNumberOfPrefabs; i++)
        {
            spawnedEntity = GetGame().SpawnEntityPrefab(resource, GetGame().GetWorld(), params);
            if (!spawnedEntity)
                continue;
 
            numberOfSuccesfullySpawnedEnts++;
            PostPrefabSpawn(spawnedEntity);
            SCR_MultiPartDeployableItemComponent.SetAuthor(spawnedEntity, authorPlayerId);
 
            spawnedIIC = InventoryItemComponent.Cast(spawnedEntity.FindComponent(InventoryItemComponent));
            if (spawnedIIC)
                spawnedIIC.PlaceOnGround(user);
        }
 
        return numberOfSuccesfullySpawnedEnts == m_iNumberOfPrefabs;
    }
 
    //------------------------------------------------------------------------------------------------
    void PostPrefabSpawn(notnull IEntity spawnedEntity);
}